Все варианты целей, условий и модификаторов возвращают значение «истина», вы можете добавить приписку no к цели, условию или модификатору, чтобы исключить указанную цель, условие или модификатор. Например:

/cast [mod:shift,combat] Пинок - заклинание будет использоваться только если у вас зажат шифт при использовании макроса и вы в бою
/cast [mod:shift,nocombat] Пинок - заклинание будет использоваться только если у вас зажат шифт при использовании макроса и вы НЕ в бою
/cast [nomod:shift,nocombat] Пинок - заклинание будет использоваться только если у вас НЕ зажат шифт при использовании макроса и вы НЕ в бою

Список возможных целей:

@player - игрок (вы)

@target - ваша текущая цель, уже практически не используется, вместо этого используют []

@mouseover - цель, на которую наведен курсор мыши

@cursor - место, куда наведен курсор мыши (например для Отвлечения | Абордажного крюка)

@focus - запомненная цель (фокус)

@targettarget - цель вашей цели (например если вы выделили босса, то макрос будет использован на танка, которого бьет босс)

@boss1-5 - номер босса из босс фреймов сверху вниз (@boss1, @boss2 и т.д.)

@arena1-3 - номер противника на арене сверху вниз.

@pet - ваш питомец

Список условий:

pet - истина, если нету питомца

combat - истина, если вы в бою

harm - истина, если цель - враг

help - истина, если цель - союзник

dead - истина, если цель мертва

exists - истина, если цель существует (например выбран фокус)

channeling - истина, если вы сейчас применяете заклинание (не моментальное, например вызов маунта)

button:номер - (или btn) используется для проверки с какой кнопки вы активируете макрос. [button:1] по умолчанию - левая кнопка мыши, [button:2] - правая, [button:3] центральная. Другие кнопки на мышке зависят от ваших настроек мыши

known:id (или название) - известно ли заклинание

equipped:слот - (или worn) истина, если в слоте надета вещь. Например [equipped:chest] будет истиной, если у вас надета грудь

spec:номер - истина, если выбрана указанная специализация (сверху вниз). У разбойников, ликвидация - 1, головорез - 2, скрытность - 3

group - истина, если вы в группе. Можно указывать конкретнее, например [group:party] или [group:raid].

indoors - истина, если вы находитесь в локации, которая считается "в помещении" (рейды, арены, подземелья и т.д.)

outdoors - истина, если вы находитесь в локации, которая считается "вне помещения" (открытый мир / столицы)

flyable - истина, если в этом месте можно летать

mounted - истина, если вы на маунте

flying - истина, если вы летите

swimming - истина, если вы плывете

Список модификаторов:

mod:shift - истина, если кнопка (макроса) нажимается пока зажат SHIFT

mod:alt - истина, если кнопка (макроса) нажимается пока зажат ALT

mod:ctrl - истина, если кнопка (макроса) нажимается пока зажат CTRL

#showtooltip
/cast [known:382245] Хладнокровие
/cast [spec:1] Отравление
/cast [spec:2] Устранение
/cast [spec:3, known:280719] Тайный прием
/cast [noknown:280719] Продолжительная отповедь

Рваная рана используется в курсор мыши, если там враг. Если под курсором союзник | вы | никого нету, то используется в текущую цель. С контролом используется по фокусу

#showtooltip
/cast [nomod,@mouseover, harm][mod:ctrl,@focus][] Рваная рана

#showtooltip
/cast
[spec:1,nomod] Веер клинков; [spec:1,mod:shift] Кровавый вихрь;
[spec:2,nomod] Шквал клинков; [spec:2,mod:shift,known:271877] Натиск клинка
[spec:3,nomod] Шквал сюрикэнов; [spec:3,mod:shift] Черный порох

Все варианты подлечиться в 1 кнопке, на ALT можно поставить личку / бинты / что угодно

#showtooltip
/cast [nomod] Алый фиал
/cast [mod:shift] Камень здоровья
/cast [mod:ctrl] Освежающее лечебное зелье

#showtooltip
/cast [nomod][mod:ctrl, @focus, exists, nodead] Пинок; [mod: alt, @focus, exists, nodead] Ошеломление

Без модификатора - если под курсором союзник, то кидает в него, иначе кидает в вашу цель. С SHIFT / CTRL - первый / второй танк в вашем рейде (ники вписать руками вместо НИК1 и НИК2). С ALT - на первую позицию в группе (сверху вниз), это всегда лидер группы (в м+ обычно это танк)

#showtooltip 
/cast [nomod, @mouseover, help][mod:shift, @НИК1][mod:ctrl, @НИК2][mod:alt,@party1][] Маленькие хитрости

Отменяет танец теней (т.к. в нем нельзя зайти в незаметность) и использует незаметность (повторные нажатия не выводят из незаметности)

#showtooltip
/cancelaura [nocombat] Танец теней
/cast !Незаметность

Используется для поиска других рог / друидов в незаметности (нужно спамить макрос)

#showtooltip
/cleartarget
/targetenemyplayer
/cast Ошеломление

Без модификатора - шаг сквозь тень в текущую цель. С CTRL - в первую позицию в группе (лидер пати). С SHIFT - Шаг сквозь тень + пинок по фокусу, нужно нажимать 2 раза, если не нажать 2ой раз в течении 3 секунд, то следующее применение снова использует Шаг сквозь тень, а не Пинок (сделано для скрытности, т.к. там 2 заряда). С ALT - шаг сквозь тень + ошеломление (используется против ДХ с глазами). Также этот макрос сбрасывает с вас Длань свободы паладина (фридом), сделано это чтобы маги не воровали бафф, можно удалить эту строчку

#showtooltip
/stopattack
/cast [nomod][mod:ctrl, @party1] Шаг сквозь тень
/castsequence [mod:shift, @focus, harm] reset=3 Шаг сквозь тень, Пинок
/castsequence [mod:alt] reset=3 Шаг сквозь тень, Ошеломление

#showtooltip
/cast [nomod][mod:shift, @arena1] [mod:ctrl, @arena2] [mod:alt, @arena3] Ослепление

Довольно большой макрос на все варианты бурстов саба, создан для того, чтобы не терять миллсекунды при начале опенера (иногда из-за реакции, пинга, окна очереди и прочего теряется целое гкд в танце)

/cqs
/cast [nomod:alt]Танец теней
/cast Символы смерти
/cast [mod:alt]Теневые клинки
/cast [mod:shift,noknown:382505]Удар тьмы;[mod:shift,known:382505]Клинок мрака;[mod:alt]Клинок мрака
/cast [nomod:alt]Скорополоховый чай
/cast [mod:ctrl]Шквал сюрикэнов

Пояснения:
/cqs - отменяет очередь окна заклинаний, чтобы ничего лишнего не нажалось

При нажатии без модификатора нажимается: Танец + Символы + Чай

При нажатии с шифтом: Танец + Символы + Чай + Клинок мрака (если взят талант Первый танец), либо Удар тьмы (если не взят талант)

При нажатии с контролом: Танец + Символы + Чай + Шквал сюрикэнов

При нажатии с альтом: Символы + Теневые клинки + Клинок мрака (стандартное начало опенера если взят талант Первый танец)

Пример ст ротации: удар тьмы - макрос с альтом - рваная рана - макрос с шифтом (если есть поиск слабости) или макрос с контролом (если нету поиска слабости) - дальнейшая ротация